;-------------------
; Hexdump ver0.0.1
;-------------------

CODE SEGMENT
ASSUME CS:CODE, DS:CODE,ES:CODE,SS:CODE
ORG 80H
CMDLN DB 128 DUP(0)

ORG 100H
        
START:
MOV AH,9 ;INT21Hシステムコール　AH=9 :文字列の表示
MOV DX, OFFSET STARTMES　　;DX=文字列先頭アドレス
INT 21H ;スタートメッセージ表示
MOV BL, CMDLN ;BL＝コマンドライン文字数
MOV BH,0
MOV CMDLN[BX+1],0 ;コマンドライン（＝ファイル名）のASCIZ化　（文字列の末尾に0を追加）
MOV AH,3DH　　　　　;INT21Hシステムコール　AH=3DH:ファイルオープン
MOV AL,0　　　　　　;AL=0 :読出しモード
MOV DX,OFFSET CMDLN+2 ;ファイル名をDXにセット
INT 21H ;ファイルのオープン　正常にファイルオープンできた場合はAXにファイルハンドル
JC OERROR1　　　　　;キャリーフラグがセットされた場合はエラー（AXにエラーコード）−＞OERROR1へ
MOV FHANDLE, AX　　 ;FHANDLE=AX（ファイルハンドル）
MOV AH,3EH　　　　　;INT21Hシステムコール　AH=3EH　:ファイルクローズ
MOV BX,FHANDLE ;BX:ファイルハンドル 
INT 21H ;ファイルハンドルのクローズ

      

;--------------------------------------------------------
;コマンド入力ルーチン
;--------------------------------------------------------
CONL:
CALL PRINTCRLF　　　;改行ルーチンのコール
MOV AH,2
MOV DL,'-'
INT 21H　　　　　　;コマンド入力待ち　'-'の表示
MOV AH,0AH　　　　　　　;INT21Hシステムコール　AH=0AH：キーボード入力       
MOV DX,OFFSET CONBUF   ;DX：入力バッファアドレス   
INT 21H                ;キーボードからのコマンド入力
CMP CONBUF[2],'D'   ;コマンドの判定
JZ DUMPL            ;'D'ならダンプ表示へ
CMP CONBUF[2],'Q'
JZ FIN1             ;'Q'なら終了へ
CMP CONBUF[2],'C'
JZ CHECK            ;'C'ならバイナリデータ検索へ
JMP CONL            ;コマンド入力へ戻る

CHECK:
CALL CHECKL　　　　　;バイナリデータ検索ルーチンコール
JMP CONL

FIN1:
INT 20H             ;終了

;-----------------------------------------------------
;ダンプ表示
;-----------------------------------------------------
DUMPL:
MOV AH, 3DH　　　　　　　;INT21Hシステムコール　AH=3DH：ファイルオープン
MOV AL,0                 ;AL=0 読出しモード
MOV DX, OFFSET CMDLN+2　 ;DX:パス名の先頭アドレス
INT 21H　　　　　　　　　;ファイルオープン
MOV ADDRESS, WORD PTR 0
JMP LOOPL

OERROR1:
JMP OERROR

LOOPL:
MOV AH,6
MOV DL,0FFH
INT 21H           ;キーボードから１文字入力 ALに入力データがリターンされる
CMP AL,'1'        ;押されたキーの判定
JZ LSTOP          ;１なら一時中断
CMP AL, '2'
JZ LRESTART       ;２なら再開
CMP AL, '3'
JZ FINISH         ;３なら終了
JMP LOOP1

FINISH:
INT 20H

LSTOP:
MOV CONDF,1       ;CONDFフラグを１にする。（一時中断状態）
JMP LOOP1

LRESTART:
MOV CONDF,0       ;CONDFフラグを０にする。（ダンプ実行）

LOOP1:
CMP CONDF,1
JZ LOOPL          ；CONDFフラグが１ならLOOPLに戻り、ループ（待ち状態）継続

LOOPA:
CALL PRINTCRLF
CALL PRINTADR     ;アドレス表示プロシージャのコール
CALL LINEBUFINIT  ;キャラクタ表示用LINBUF[]の初期化
MOV BX,0
CMP KANF,0　　　　;前の行の行末は漢字ではない（KANF=0)−−＞LOOPBへ
JZ LOOPB

;--------------------------------------------------------------------------
;前の行の行末は漢字ではない（KANF=1)の場合　KANBUF−＞AL−＞LINEBUF[0]
;前の行末が漢字だった（KANF=2)場合　LINEBUF[0]には「　」（空白）を入れSKIPへ
;---------------------------------------------------------------------------
MOV AL,KANBUF　　
CMP KANF,1
JZ SKIP1
MOV LINEBUF[0],' '
MOV KANF,0
JMP SKIP

SKIP1:
MOV KANF,0
MOV LINEBUF[0],AL
JMP SKIP

LOOPB:
CALL GETC　　　;１バイト読み込み。ALに入力されたデータを保持
JNZ EOF　　　　;GETCプロシージャコールの結果、Zフラグ=0（読み込まれたデータがない）ならEOFへ
MOV LINEBUF[BX],AL　　;LINEBUF[BX]=AL　

SKIP:
CMP AL,CHECKBUF　　;AL（入力データ）とCHECKBUF（検索データ）の比較
JNZ NCOLOR　　　　 ;一致していなければNCOLORへ、一致していれば、表示色を赤に
MOV AH,9
MOV DX,OFFSET REDC　　;REDCは表示を赤にするエスケープシーケンス ...�@
INT 21H           ;表示を赤に変更
MOV CHECKF,1　　　;CHECKF　表示の色フラグ　１　赤　　０　白
MOV AL,CHECKBUF

NCOLOR:
CALL PUTHEX　　　 ;１６進数での表示
CMP CHECKF,1　　　;CHECKF=１（表示が赤）なら−＞白に戻しておく　
JNZ WHIT　　　　　;CHECKF=0（表示白）なら以下飛ばして、WHITへ
MOV AH,9
MOV DX,OFFSET WHITEC　;WHITEC　表示を白にするエスケープシーケンス
INT 21H　　　　　 ;表示を白に変更
MOV CHECKF,0　　　;CHECKFも0に戻しておく

WHITE:
INC BX　　　　　　;BX←BX+1
CMP BX, 10H　 　　;BXが16未満（１行=16文字分未処理なら）LOOPBに戻って次のデータの処理継続 
JB LOOPB 

CALL PUTC 　　　　;キャラクタ表示のコール 
ADD ADDRESS,16　　;ADDRESSを１６加算 
JMP LOOPL

        

OERROR:                 ;エラーメッセージを表示して終了
MOV DX, OFFSET OERRMES
MOV AH,9
INT 21H
INT 20H

RERROR:
MOV DX, OFFSET RERRMES
MOV AH,9
INT 21H
JMP CLOSE

EOF:　　　　　　　　　;EOF時の行末処理（0、$の付加）->キャラクタ表示
MOV LINEBUF[BX+1],0
MOV LINEBUF[BX+2],'$'
CALL PUTC

CLOSE:　　　　　　　;ファイルクローズ処理
MOV AH, 3EH
MOV BX,FHANDLE
INT 21H
JMP CONL

PRINTADR PROC　　　　;アドレス部の表示
MOV AX,ADDRESS
MOV AL,AH            ;AL<-アドレスの上位桁（AH)
CALL PUTHEX　　　　　;まず、上位桁を１６進表示
MOV AX,ADDRESS
CALL PUTHEX　　　　　;アドレスの下位桁の１６進表示
MOV DL,':'
MOV AH,2
INT 21H　　　　　　　;':'の表示
RET
PRINTADR ENDP 

CHECKL PROC　　　　;検索データ（Cコマンド）処理
MOV AL,CONBUF[3]　　;CONBUF[3]：検索したいデータの上位バイト（キャラクタコード）
CALL HENKAN　　　　;キャラクタコード->バイナリー値
SAL AL,1　　　　　;４回左シフトして、上位４ビットに値をシフト
SAL AL,1
SAL AL,1
SAL AL,1
MOV AH,AL　　　　　;AH<-AL　AHに検索したいデータの上位バイトがバイナリー値（上位４ビット）としてセットされた
MOV AL,CONBUF[4]　　;CONBUF[4]：検索したいデータの下位バイト（キャラクタコード）
CALL HENKAN　　　　;ALに検索したいデータの下位バイトがバイナリー値（下位４ビット）としてセットされた
ADD AH,AL　　　　　;AH←AH（上位バイト）＋AL（下位バイト）
MOV CHECKBUF,AH　　;CHECKBUF：検索データ
RET

;キャラクタコード−>バイナリデータ変換
HENKAN:
CMP AL,30H
JB CHECKEND　　　　;キャラクタコード30H未満はCHECKENDへ
CMP AL,39H
JBE ZERO　　　　　;30H〜39H（数字の０〜９）はZEROへ
CMP AL,41H
JB CHECKEND
CMP AL,46H　　　　;41H〜46H（アルファベット小文字a〜f）はHEXへ
JBE HEX
JMP CHECKEND

ZERO:　　　　;30H(=48)を引いて、数値（0〜9）に変換
SUB AL,30H
RET

HEX:　　　　　;37Hを引いて、数値（aH = 10 〜 fH =16）に変換
SUB AL,37H
RET

CHECKEND:
MOV AL,0
RET
CHECKL ENDP

;----------------------------------------------------------------
;１６進数での表示　バイナリデータ−＞キャラクタコード
;----------------------------------------------------------------
PUTHEX PROC
MOV CHARA,AL　;CHARA=AL（入力データ）
AND AL,0F0H　　;下位桁をマスク
SHR AL,1       ;４回右シフトして
SHR AL,1
SHR AL,1
SHR AL,1
CALL HEXDISP　　;上位桁表示
MOV AL,CHARA
AND AL,0FH　　　;上位桁マスク
CALL HEXDISP　　;下位桁表示
MOV DL,' '
MOV AH,2
INT 21H　　　　;空白を１個表示
RET

;--------------------------------------------------------------------------
;16進数として表示。
;0〜9は30H足して、aH=10 〜fH=16 は37H足してキャラクタコードに変換してDISPへ
;--------------------------------------------------------------------------
HEXDISP:　　
CMP AL,9
JA TOHEX
MOV DL,30H
ADD DL,AL
JMP DISP

TOHEX:
MOV DL,37H
ADD DL,AL

DISP:
MOV AH,2  ;INT21Hシステムコール　AH=2　文字の出力
INT 21H   ;文字の出力　DL=キャラクタコード
RET
PUTHEX ENDP

PRINTCRLF PROC　　;改行
MOV DL,0DH
MOV AH,2
INT 21H
MOV DL,0AH
MOV AH,2
INT 21H
RET
PRINTCRLF ENDP

;------------------------------------------------------------
;１バイトデータ取得
;------------------------------------------------------------
GETC PROC
PUSH BX
MOV BX,FHANDLE  ;BX=ファイルハンドル
MOV AH,3FH      ;INT21Hシステムコール　AH=3FH：ファイル読出し　
MOV DX, OFFSET BUF　;DX=入力バッファ先頭アドレス(OFFSET BUF) 
MOV CX,1  ;CX 読み込むバイト数
INT 21H   ;ファイルの読出し　 
JC RERROR1
CMP AX,CX  ;AX:読み込まれたバイト数　CX:読み込むバイト数の比較−＞メインルーチンで判定
MOV AL,BUF  ;読み込んだキャラクタ(=BUF)はALに入れる
POP BX
RET
GETC ENDP

RERROR1:
JMP RERROR

LINEBUFINIT PROC　　　;キャラクタ表示用LINEBUF[]の初期化
MOV CX,16
INITS:　　　;LINEBUF[]を0に初期化
MOV SI,CX
MOV LINEBUF[SI],0
LOOP INITS　;CX <--CX-1 CX=0になるまでループ（１６回）　
RET
LINEBUFINIT ENDP

;------------------------------------------------
;キャラクタ表示
;------------------------------------------------
PUTC PROC
MOV BX,0

PUTCS:
MOV AL,LINEBUF[BX]
CMP AL,20H
JB NOASCI　　;キャラクタコードが20H未満ならNOASCI（文字でない）の処理へ
CMP AL,24H
JZ NOASCI
CMP AL,80H
JB ASCI      ;20Hから7FHはASCI(１バイト文字処理）へ
CMP AL,9FH　
JBE KANJI　　;80Hから9FHはKANJI（漢字処理）へ
CMP AL,0E0H
JB ASCI　　　;A0HからDFHはASCI(１バイト文字処理）へ
CMP AL,0FCH
JBE KANJI　　;E0HからFCHはKANJI（漢字処理）へ

NOASCI:
MOV LINEBUF[BX],'.'
JMP ASCI

KANJI:
CMP BX,15
JZ KANJI15　　;行末（BX=15)ならKANJI15（行末漢字処理）へ
MOV AH,LINEBUF[BX+1]　;２バイト目(LINEBUF[BX+1])をAHに読み込み
CALL ISKANJI2　　　　;２バイト目が漢字コードかどうかの判定へ
CMP KAN2,1　　　;KAN2=１　漢字コードなら
JZ KANTRUE　　　;KANTRUE（漢字表示）へ
MOV LINEBUF[BX],'.'　　　;漢字でないなら'.'の表示
JMP ASCI

KANTRUE:
INC BX
JMP ASCI

KANJI15:　　;行末の場合の漢字（２バイト文字）の処理
CALL GETC　　;次の行の先頭の１バイトを読み込み
MOV AH,AL
CALL ISKANJI2　;２バイト目が漢字コードかどうかの判定
CMP KAN2,1
JZ KANTRUE15　　;KAN2=1　漢字ならKANTRUE15（行末の漢字表示）へ
MOV KANF,1　　　;漢字でなければKANF=1に設定　
MOV KANBUF,AH　　;先読みした次の行の先頭バイト（AH)をKANBUFに保存。次の行の処理で使う
MOV LINEBUF[15],'.'
MOV LINEBUF[16],' '
JMP ASCI

KANTRUE15:
MOV LINEBUF[16],AH
MOV KANF,2　　　　　;KANF=2　行末は漢字だった。
MOV KANBUF,AH

ASCI:
INC BX
CMP BX,16
JAE PUTCEND　;１行分（１６データ）処理したらPUTCENDへ
JMP PUTCS　　;１６データ未満ならPUTCSに戻って処理を継続
PUTCEND:
MOV AH,9
MOV DX, OFFSET LINEBUF[0]
INT 21H　　　;１行分のキャラクタ表示
RET

;----------------------------------------------------------
;２バイト目が漢字コードかどうかの判定
;40H〜7EH  80H〜FCHなら漢字　−＞KAN2フラグ=１   
;----------------------------------------------------------
ISKANJI2:　　　
CMP AH,40H
JB FALSE
CMP AH, 7EH
JBE TRUE
CMP AH,80H
JB FALSE
CMP AH,0FCH
JBE TRUE

FALSE:
MOV KAN2,0
RET

TRUE:
MOV KAN2,1
RET

PUTC ENDP

STARTMES DB 'HEXDUMP ver0.1  <制作  河西  毅>',0Dh,0AH
         DB 'コマンド',0DH,0AH
         DB 'D  バイナリーダンプ  以下のサブコマンドがあります',0DH,0AH
         DB '１  中断     ２  再開     ３  終了',0DH,0AH
         DB  'Q  HEXDUMP終了',0DH,0AH
         DB  'C  バイナリデータ検索  指定したデータが赤色で表示。 指定例）C38, C7E',0DH,0AH
         DB  '全て大文字で指定して下さい',0DH,0AH,'$'
OERRMES  DB 'ファイルが開けません。コマンドラインに正しいファイル名を指定して下さい',0DH,0AH,'$'
RERRMES  DB 'データ読み込みエラー',0DH,0AH,'$'
REDC DB 1BH,'[31m$'
WHITEC DB 1BH,'[m$'
FHANDLE DW 0
ADDRESS DW 0
CHARA DB 0
BUF DB 0
KANF DB 0
KANBUF DB 0
KAN2 DB 0
CONDF DB 0
CONBUF DB 4,5 DUP(0)
CHECKBUF DB 0
CHECKF DB 0
LINEBUF DB 17 DUP(0),'$'

CODE ENDS
END START